Dynamisches Form, wieso kommt bei KeyDown immer 255

[Mathias]

Bei folgendem Miniprogramm, kommt bei KeyDown immer 255.
KeyPress funktioniert wie erwartet.
Probiert mit Linux.

Code: Alles auswählen

program Project1;
uses
  Interfaces, Forms, Controls, Classes;

type
  TApp = class(TObject)
  private
    Form: TForm;
    procedure KeyDown(Sender: TObject; var Key: word; Shift: TShiftState);
    procedure KeyPress(Sender: TObject; var Key: char);
  public
    constructor Create;
    destructor Destroy; override;
    procedure Run;
  end;

  procedure TApp.KeyDown(Sender: TObject; var Key: word; Shift: TShiftState);
  begin
    WriteLn(Key);
  end;

  procedure TApp.KeyPress(Sender: TObject; var Key: char);
  begin
    WriteLn(Key);
  end;

  constructor TApp.Create;
  begin
    inherited Create;
    Form := TForm.Create(nil);
    Form.OnKeyDown := @KeyDown;
    Form.OnKeyPress := @KeyPress;
  end;

  destructor TApp.Destroy;
  begin
    Form.Free;
    inherited Destroy;
  end;

  procedure TApp.Run;
  begin
    Form.ShowModal;
  end;

var
  App: TApp;
begin
  App := TApp.Create;
  App.Run;
  App.Free;
end.

Folgende Methoden funktionieren auch ohne Fehler:

Code: Alles auswählen

  Form.OnPaint := @FormPaint;
  Form.OnResize := @FormResize;
  Form.OnKeyPress := @FormKeyPress;
  Form.OnMouseDown := @FormMouseDown;
  Form.OnMouseMove := @FormMouseMove;
  Form.OnMouseUp := @FormMouseUp;   

[Winni]

Hi!

Ganz einfach: Deine App gründet auf TObject und nicht auf TForm.

TObject hat keine KeyDown/KeyUp/KeyPress event.
Im Ggs zur TForm.

Die KeyXXX events werden erst in der TWinControl eingeführt.

Entweder die Klasse wechseln .
Oder die Key events selber implementieren .

Dein Project war nicht zu öffnen.
Irgendwo muss man das Kompatibitäts-Bit setzen hab ich mal irgendwo diagonal gelesen.

Winni

[Mathias]

Oder die Key events selber implementieren .

Das wäre die besze Lösung, aber ich habe keinen Ansatz, wie das geht.

Dein Project war nicht zu öffnen.
Irgendwo muss man das Kompatibitäts-Bit setzen hab ich mal irgendwo diagonal gelesen.

Lazarus trunk und stable sind nicht kompatibel.

[sstvmaster]

Dein Project war nicht zu öffnen.
Irgendwo muss man das Kompatibitäts-Bit setzen hab ich mal irgendwo diagonal gelesen.

Winni

Kann man hier im Trunk einstellen: viewtopic.php?p=117246#p117246
Damit läuft dann auch ein Trunk Projekt mit älteren Versionen.

[Mathias]

Ich habe es mal mit einer direkten Vererbung von TForm probiert, dabei kommt bei Key immer noch 255.

Code: Alles auswählen

uses {$IFDEF UNIX} {$IFDEF UseCThreads}
  cthreads, {$ENDIF} {$ENDIF}
  Interfaces, Classes, SysUtils, Forms, Controls, Graphics, Dialogs, ExtCtrls, StdCtrls;

type
  TMyForm = class(TForm)
  private
    procedure FormKeyDown(Sender: TObject; var Key: word; Shift: TShiftState);
    procedure FormKeyPress(Sender: TObject; var Key: char);
  public
    constructor Create(TheOwner: TComponent); override;
  end;

  { TMyForm }

  procedure TMyForm.FormKeyDown(Sender: TObject; var Key: word; Shift: TShiftState);
  begin
    WriteLn(Key);  // kommt immer 255
  end;

  procedure TMyForm.FormKeyPress(Sender: TObject; var Key: char);
  begin
    WriteLn(Key);  // geht
  end;

  constructor TMyForm.Create(TheOwner: TComponent);
  begin
    inherited Create(TheOwner);
    OnKeyDown := @FormKeyDown;
    OnKeyPress := @FormKeyPress;
  end;

var
  App: TMyForm;

begin
  App := TMyForm.Create(nil);
  App.ShowModal;
  App.Free;
end.

[Winni]

Hi!

Auf jeden Fall mss mal KeyPreview der Form auf true gestellt werden.
Default ist false;

Winni

[Mathias]

Danke für die Info, habe unterdessen den Fehler selbst gefunden.

Mit "Application.Initialize" geht es, wieso auch immer.

Code: Alles auswählen

var
  App: TMyForm;

begin
  Application.Initialize; // Muss eingefügt werden.
  App := TMyForm.Create(nil);
  App.ShowModal;
  App.Free;
end.  

[Winni]

Hi!

Dann guck Dir doch mal an, wie eine "normale" lpr Datei aussieht, z.B.:

Code: Alles auswählen

program CssValues;
{$mode objfpc}{$H+}

uses
   {$IFDEF UNIX}{$IFDEF UseCThreads}
   cthreads,
   {$ENDIF}{$ENDIF}
   Interfaces, // this includes the LCL widgetset
   Forms,
   { you can add units after this }
   CssValues1;

{$R *.res}

begin
   RequireDerivedFormResource:=True;
   Application.Scaled:=True;
   Application.Initialize;
   Application.CreateForm(TForm1, Form1);
   Application.Run;
end.    

Immer in dieser Reihenfolge:

Code: Alles auswählen

Application.Initialize;
Application.CreateForm;
Application.Run;

Winni

[Mathias]

Genau dort hatte ich es gefunden .