Schriftgröße bei TextRect auf Printer.Canvas

[AlterMann]

Hallo

Schon wieder so eine leidige Druckerfrage

Code: Alles auswählen

 
     r.Left:=x1;
      r.right:=x8;
      r.top:=y13;
      r.bottom:=y14;
      Printer.Canvas.Font.Name := 'Arial';
      Printer.Canvas.Font.Size:=140;
      druckstyle.Alignment:=taCenter;
      druckstyle.Layout:=tlCenter;
      druckstyle.Wordbreak:=true;
      druckstyle.Singleline:=false;
      Printer.Canvas.TextRect(r,1,1,s,druckstyle);
 

Der Text in s wird zwar korrekt Zentriert aber die Schrift ist winzig klein, egals was in Printer.Canvas.Font.Size drin steht.
Ich werd' noch wahnsinnig ...

Hat wer eine Idee?

Schönen Sonntag
Christian

[theo]

Kann ich nicht nachvollziehen.

Dieser Code:

Code: Alles auswählen

procedure TForm1.Button1Click(Sender: TObject);
var r:TRect;
  druckstyle:TTextStyle;
begin
  if PrintDialog1.Execute then
  begin
    Printer.BeginDoc;
    Printer.Canvas.Font.Name := 'Arial';
    Printer.Canvas.Font.Size:=18;
    druckstyle.Alignment:=taCenter;
    druckstyle.Layout:=tlCenter;
    druckstyle.Wordbreak:=true;
    druckstyle.Singleline:=false;
    r.Left:=Printer.PaperSize.PaperRect.WorkRect.Left+10;
    r.Top:=Printer.PaperSize.PaperRect.WorkRect.Top+40;
    r.Right:=Printer.PaperSize.PaperRect.WorkRect.Right-20;
    r.Bottom:=r.Top+Printer.Canvas.TextHeight('AZ');
    Printer.Canvas.Rectangle(r);
    Printer.Canvas.TextRect(r,r.Left,r.Top,'hallo test hallo test',druckstyle);
    Printer.EndDoc;
  end;
end; 

Druckt bei mir das angehängte Dokument.
Lazarus 1.3 r44647M FPC 2.7.1 x86_64-linux-gtk 2

[m.fuchs]

Schau mal, ob dir das hier hilft: http://www.lazarusforum.de/viewtopic.php?p=57732#p57732

[AlterMann]

Danke euch beiden für die Antworten

@Michael:
Den Beitrag mit den falschen dpi-Werten hatte ich auch schon gefunden, das ist bei mir nicht der Fall.
Drucker hat 600dpi, das wird auch angezeigt.

@theo:
Danke für's ausprobieren.
Dein Code funktioniert in meinem Programm genauso wie bei Dir.

Allerdings nur wenn ich die Variable r vor druckstyle deklariere!!! (Im Code der erste - nicht auskommentierte - Teil)

Mach ich es umgekehrt druckt er die falsche Variante. (siehe Anhänge gut.pdf und schlecht.pdf)

Dumm ist nur, daß ich in meiner Originalroutine die Variablen in der "richtigen" Reihenfolge deklariere, es aber trotzdem falsch druckt.

Ich meine irgendwo gelesen zu haben, daß TRect in verschieden Units unterschiedlich definiert sei.
Meint ihr, daß das die Lösung sein könnte?

Eine Linie Diagonal durch r gezeichnet scheint korrekt gezeichnet zu werden, trotzdem ist die Schrift wunzig klein.

Ich glaub ich gehör' bald ins Bett (oder in die Klapse!)

Code: Alles auswählen

procedure TForm1.Button18Click(Sender: TObject);//Komm drucken
 
 var r:TRect;
   druckstyle:TTextStyle;
 begin
   if PrintDialog1.Execute then
   begin
     Printer.BeginDoc;
     Printer.Canvas.Font.Name := 'Arial';
     Printer.Canvas.Font.Size:=36;
     druckstyle.Alignment:=taCenter;
     druckstyle.Layout:=tlCenter;
     druckstyle.Wordbreak:=true;
     druckstyle.Singleline:=false;
     r.Left:=Printer.PaperSize.PaperRect.WorkRect.Left+10;
     r.Top:=Printer.PaperSize.PaperRect.WorkRect.Top+40;
     r.Right:=Printer.PaperSize.PaperRect.WorkRect.Right-20;
     r.Bottom:=r.Top+Printer.Canvas.TextHeight('AZ');
     Printer.Canvas.Rectangle(r);
     Printer.Canvas.TextRect(r,r.Left,r.Top,'hallo test hallo test',druckstyle);
     Printer.EndDoc;
   end;
 end;
{var druckstyle : TTextStyle;
    r : TRect;
begin
 if PrintDialog1.Execute then
  begin
 Printer.BeginDoc;
 
Printer.Canvas.Font.Name := 'Arial';
Printer.Canvas.Font.Size:=36;
druckstyle.Alignment:=taCenter;
druckstyle.Layout:=tlCenter;
druckstyle.Wordbreak:=true;
druckstyle.Singleline:=false;
r.Left:=Printer.PaperSize.PaperRect.WorkRect.Left+10;
r.Top:=Printer.PaperSize.PaperRect.WorkRect.Top+40;
r.Right:=Printer.PaperSize.PaperRect.WorkRect.Right-20;
r.Bottom:=r.Top+Printer.Canvas.TextHeight('AZ');
Printer.Canvas.Rectangle(r);
Printer.Canvas.TextRect(r,r.Left,r.Top,'hallo test hallo test',druckstyle);
Printer.Enddoc;
end;
   //if MeinPrintDialog then
 // if CheckBox16.Checked then Kommissiondrucken(true) else Kommissiondrucken(false);
end;  }
 

gut.pdf

(2.76 KiB) 86-mal heruntergeladen

schlecht.pdf

(6.62 KiB) 69-mal heruntergeladen

[AlterMann]

Update:

Hab versucht r als classes.TRect sowie als windows.TRect zu deklarieren.

Beides negativ

[AlterMann]

Nur zru Verdeutlichung:

Code: Alles auswählen

 
var r:TRect;
      druckstyle:TTextStyle;
 

funktioniert ...

Code: Alles auswählen

 
var druckstyle:TTextStyle;
      r:TRect;
 

nicht ....

[theo]

Das kann ich nicht nachvollziehen. Es ergibt ja auch wirklich überhaupt keinen Sinn.
Ich glaube dein Problem liegt woanders.

[Michl]

Ich kann das Fehlverhalten bestätigen, wobei Laz. 1.2.0 und Laz.1.3-Trunc (Win64bit Laz.32bit) jeweils auch noch unterschiedliche Verhalten zeigen. Heaptrc zeigt nichts an. Ich denke, das Verhalten ist ein Bugtrackereintrag wert!

Wobei der Unterschied jeweils in der Reihgenfolge der Deklaration von druckstyle:TTextStyle und r:TRect liegt. Da ich es auch anfangs nicht glauben konnte habe ich das mehrfach hintereinander probiert, immer mit dem gleichen Ergebnis. Siehe unten.

[theo]

Ich habe es auf
Lazarus 1.3 r44721M FPC 2.7.1 x86_64-linux-gtk 2
CompilerDate=27.02.2014
getestet und konnte kein Problem feststellen.

[Michl]

Muss/Kann man sonst noch was einstellen?!?

Code: Alles auswählen

{$DEFINE Test1}
 
procedure TForm1.Button1Click(Sender: TObject);
{$IFDEF Test1}
var
  druckstyle:TTextStyle;
  r:TRect;
{$ELSE}
var
  r:TRect;
  druckstyle:TTextStyle;
{$ENDIF}
begin
  if PrintDialog1.Execute then
  begin
    Printer.BeginDoc;
    Printer.Canvas.Font.Name := 'Arial';
    Printer.Canvas.Font.Size:=18;
    Printer.Canvas.Font.PixelsPerInch := 600;
    druckstyle.Alignment:=taCenter;
    druckstyle.Layout:=tlCenter;
    druckstyle.Wordbreak:=true;
    druckstyle.Singleline:=false;
    r.Left:=Printer.PaperSize.PaperRect.WorkRect.Left+10;
    r.Top:=Printer.PaperSize.PaperRect.WorkRect.Top+40;
    r.Right:=Printer.PaperSize.PaperRect.WorkRect.Right-20;
    r.Bottom:=r.Top+Printer.Canvas.TextHeight('AZ');
    Printer.Canvas.Rectangle(r);
    Printer.Canvas.TextRect(r,r.Left,r.Top,'hallo test hallo test',druckstyle);
    Printer.EndDoc;
  end;
end;     

Unterschied ist in definertem Test1 zu erkennen.

Könnt eine undefinierte Variable sein...

[theo]

Vllt mal so probieren:

Code: Alles auswählen

var
  Rec: TRect;
  Style: TTextStyle;
begin
  FillChar(Style, SizeOf(TTextStyle), 0);
  Style.Opaque := True;
  Style.SystemFont := True;

[Michl]

Mit

Code: Alles auswählen

    druckstyle.Opaque:=True;
    druckstyle.SystemFont:=False;   

ist bei mir dann alles gut und es wird immer das gleiche Ergebnis geliefert, egal ob Laz1.2/1.3 oder mit/ohne Test1. Stelle ich Systemfont auf True, nimmt er keinerlei Größenänderungen an.

Theo, hast wie immer den Finger drauf!

[theo]

Dann ist's ja gut. Du hattest also recht mit der "undefnierten Variablen" resp. "nicht initialisierten" Variablen.

[AlterMann]

Ihr seid spitze!

Mit

Code: Alles auswählen

    druckstyle.Opaque:=True;
    druckstyle.SystemFont:=False;   

ist bei mir dann alles gut und es wird immer das gleiche Ergebnis geliefert, egal ob Laz1.2/1.3 oder mit/ohne Test1. Stelle ich Systemfont auf True, nimmt er keinerlei Größenänderungen an.

Theo, hast wie immer den Finger drauf!

Bei mir auch!
Darauf muß man einmal kommen.

Vielen, vielen Dank!