ComboBox doppelte Einträge

[Mathias]

Bei TStringList gibt es

Code: Alles auswählen

sl.Duplicates := dupIgnore;  

Gibt es so was auch direkt für die ComboBox.Items ?

Oder muss ich den Umweg über eine temporäre StringList machen, um die Doppelten Einträge zu entfernen ?

[wp_xyz]

Code: Alles auswählen

constructor TCustomComboBox.Create(TheOwner : TComponent);
begin
  inherited Create(TheOwner);
  ...
  FItems := TStringlist.Create;     
  ... 

Im Constructor von TCustomCombobox sieht man, dass die Items der Combobox als TStringlist erzeugt werden. Sie sind zwar nur als TStrings veröffentlicht, aber mit einem Typecast auf TStringlist müssten die Properties von TStringlist zugänglich werden:

Code: Alles auswählen

 TStringList(Combobox1.Items).AllowDuplicate := dupIgnore;

[Mathias]

Mit folgenden einfachen Code funktioniert es nicht, das "123" kommt genau so viel mal, wie ich auf den Button klicke.
Auch wen ich den ausgeklammerten Sort nehme geht es nicht.

Code: Alles auswählen

procedure TForm1.FormCreate(Sender: TObject);
begin
  //  ComboBox1.Sorted := True;
  TStringList(ComboBox1.Items).Sorted := True;
  TStringList(ComboBox1.Items).Duplicates := dupIgnore;
end;
 
procedure TForm1.Button1Click(Sender: TObject);
begin
  ComboBox1.Items.Add('123');
end;

Wie kommst du auf AllowDuplicate, dies wird vom Kompiler gar nicht erkannt ?

[Michl]

Das mit dem Casten auf ein TStringList ist gefährlich, da die LCL Controls nativ sind. Zum Erstellen des Controls wird eine Dummy-TStringList verwendet. Wurde das Handle erstellt, wird ab dann z.B. unter Windows eine TWin32ListStringList bzw. TWin32ComboBoxStringList (direkte Nachfahren von TStrings) verwendet.

Code: Alles auswählen

procedure TForm1.Button1Click(Sender: TObject);
begin
  TWin32ComboBoxStringList(ComboBox1.Items).Sorted := True;  // dieser Cast geht
  TStringList(ComboBox1.Items).Duplicates := dupIgnore;      // dieser geht nicht
  ComboBox1.Items.Add('123');
end;   

[theo]

Dann mach halt so:

Code: Alles auswählen

  if ComboBox1.Items.IndexOf('123') < 0 then ComboBox1.Items.Add('123');  

[Mathias]

Danke, dies ist eine elegante Lösung.

Mein Ziel ist, eine ComboBox, die ähnlich funktioniert, wie der Menupunkt "Wieder öffnen...".

Code: Alles auswählen

procedure TForm1.Button7Click(Sender: TObject);
var
  sdd: TSelectDirectoryDialog;
  ini: TIniFile;
  i: integer;
  sl: TStringList;
const
  INIKey='tut_pfad';
begin
  ComboBox1.Clear;
  ini := TIniFile.Create(ConfigINIDatei);
 
  sl := TStringList.Create;
  ini.ReadSection(INIKey, sl);
  for i := 0 to sl.Count - 1 do begin
    ComboBox1.Items.Add(ini.ReadString(INIKey, sl[i], ''));
  end;
  sl.Free;
 
  sdd := TSelectDirectoryDialog.Create(Self);
  if sdd.Execute then begin
    i:=ComboBox1.Items.IndexOf(sdd.FileName);
    if i >= 0 then begin
      ComboBox1.Items.Delete(i);
    end;
    ComboBox1.Items.Insert(0, sdd.FileName);
    ComboBox1.ItemIndex := ComboBox1.Items.IndexOf(sdd.FileName);
  end;
  sdd.Free;
 
  for i := 0 to ComboBox1.Items.Count - 1 do begin
    ini.WriteString(INIKey, IntToStr(i), ComboBox1.Items[i]);
  end;
 
  ini.Free;
end;   

[Mathias]

Ich habe die Funktion ein wenig modifiziert, somit wird bei einem Duplikat, dies wieder auf die oberste Position gesetzt.

Code: Alles auswählen

procedure TSerial_Monitor_Form.Button_SendClick(Sender: TObject);
var
  i: integer;
  s: string;
begin
  s := ComboBox_Send_Text.Text;
  if Length(s) > 0 then begin
    SerWrite(SerialHandle, s[1], Length(s));

    i := ComboBox_Send_Text.Items.IndexOf(s);
    if i >= 0 then begin
      ComboBox_Send_Text.Items.Delete(i);
    end;

    ComboBox_Send_Text.Items.Insert(0, s);
    ComboBox_Send_Text.Text := s;
  end;
end;