TOpenPictureDialog und "Filter" unter Linux [gelöst]

[MmVisual]

Hallo,

Im TOpenPictureDialog habe ich Filter für Grafikdateien eingestellt, z.B.:

Joint Picture Expert Group (*.jpeg;*.jpg;*.jpe;*.jfif) | *.jpeg;*.jpg;*.jpe;*.jfif

Wenn die Datei so heißt:
Bild.jpg
dann wird dieses in der Auswahlliste gezeigt.
Hingegen die Bilder mit dem Dateiname:
Bild2.JPG, Bild3.Jpg
werden nicht gezeigt.

Kann man den Dialog so einstellen, das alle Dateien unabhängig von der Groß-/Kleinschreibung immer angezeigt werden, so wie es Windows auch macht?

Dankeschön für die Hilfe, Viele Grüße Markus.

[Roland Chastain]

Hallo!

Jemand hat hier eine Lösung angeboten.

https://forum.lazarus.freepascal.org/in ... #msg288408

Ich habe es nicht versucht. Ich weiß nicht, ob das bei Ihnen funktioniert.

[kralle]

Moin,

aus Neugier habe ich das gerade mal aus probiert.
Ergebnis: Nur Dateiendungen in Kleinbuchstaben werden angezeigt.
OS: Linux Mint 20 Cinnamon 64-Bit

Gruß HEiko

[MmVisual]

Vielen Dank für den Tipp, hier mein Code daraus

Code: Alles auswählen

// Für z.B. TFileNameEdit:
Function ChangeFileNameFilter(sFilter: String): String; // Filter-String für Linux die Groß/Kleinschreibung als Filter setzen
{$ifdef UNIX}
Var sl: TStringList;
  s, s2: String;
  i, k: Integer;
{$endif}
Begin
  {$ifdef UNIX}
  // macht aus "*.jpg" ein "*.[jJ][pP][gG]"
  sl := TStringList.Create;
  sl.Delimiter := '|';
  sl.StrictDelimiter := True;
  sl.DelimitedText := sFilter;
  For i := 0 To sl.Count - 1 Do
  Begin
    If (i Mod 2) = 1 Then
    Begin
      s := sl[i];
      For k := Length(s) DownTo 1 Do
      Begin
        s2 := LowerCase(Copy(s, k, 1));
        If s2[1] In ['a'..'z'] Then
        Begin
          s2 := '[' + s2 + UpperCase(s2) + ']';
          Delete(s, k, 1);
          Insert(s2, s, k);
        End;
      End;
      sl[i] := s;
    End;
  End;
  Result := sl.DelimitedText;
  sl.Free;
  {$else} // Windows
  Result := sFilter;
  {$endif}
End;

Procedure ChangeTDialogFilter(dlg: TFileDialog); // TDialogXXX.Filter für Linux die Groß/Kleinschreibung als Filter setzen
Begin
  {$ifdef UNIX}
  dlg.Filter := ChangeFileNameFilter(dlg.Filter);
  {$endif}
End; 

Beim FormCreate kann man automatisch alle Komponenten durchlaufen und alle TFileDialog wandeln.

[Mathias]

Interessanter Trick mit den [].
Kommt dies vom OS ?
In der Unit "Dialogs" kann ich keine [] finden.

[Socke]

Interessanter Trick mit den [].
Kommt dies vom OS ?
In der Unit "Dialogs" kann ich keine [] finden.

Das kommt vom Widgetset, wird aber von vielen Entwicklern in verschiedenen Programmen umgesetzt. Die Bash kann das z.B. auch. Stichwort: glob bzw. globbing

[Roland Chastain]

Vielen Dank für den Tipp, hier mein Code daraus

Sehr gut gemacht. Ich hätte es nicht so einfach machen können.