Inkorrekt Compilation von if und else

[Atze]

Das ist hier ein Spiel, bei dem man abwechselnd mit dem Computer Zahlen von 3-7 zum Zählerstand addiert. Wer die 100 trifft, hat gewonnen. Im Bereich bis 72 wird der Code richtig abgearbeitet. Sobald man in die oberen definierten If Bereiche kommt, wird vom Teilnehmer Computer (= Ich) das If ausgeführt aber zusätzlich das Else auch noch. Das ist unanständig und illegal... Es kommt dann zu einer doppelten Ausgabe. Nun, if und else sind entweder oder. Die Frage ist wo liegt der Fehler? Verträgt der Compiler keine gestaffelten If- Konditionen?
Wenn ich nur eine If- Kondition verwende, läuft der Code korrekt. Mit mehreren ist es buggy.

Man kann den Test abkürzen und den Zählerstand auf 70 setzen. Dann gewinnt der Computer.

[Warf]

Da eine LPI keinen code (dabei handelt es sich um die XML formatierte Projekt Datei) enthält kann man nur raten. Aber nein, gestaffelte if-then-else blöcke funktioneren sehr gut. Aber wenn du einzelstatement ifs (also ohne begin-end block) machst, kanns natürlich leicht vorkommen das man ausversehen im falschen if scope ist. Von daher immer einen begin end block starten. Ist zwar mehr tipparbeit, aber davon sind noch niemandem die Finger abgefallen und es kann viele dumme Fehler verhindern

[Linkat]

Hallo Atze,
herzlich willkommen im Lazarus-Forum.

Du musst deinen *.pas File anhängen. Mit dem .lpi kann man dir bei deinem Problem nicht helfen.

Gruß, Linkat

[charlytango]

Du musst deinen *.pas File anhängen. Mit dem .lpi kann man dir bei deinem Problem nicht helfen.

Genau zu diesem Zweck kennt Lazarus die Anweisung "Publish Project" - zu finden im Menü unter "Project - Publish Project".
Damit werden alle relevanten Dateien eines Projekts in ein "Publish" Verzeichnis kopiert und bei Bedarf gleich gezippt

[wennerer]

Hallo Atze,
deine else Abfrage bezieht sich nur auf die Abfrage zwischen 93 und 97. Ich würde deine Variable ok zur Abfrage hernehmen.

Code: Alles auswählen

program Spiel2;
var zStand,add,Du,differenz:integer;
     ok:boolean;

begin
 writeln('Spiele gegen mich');
 writeln('Wer zuerst 100 erreicht, hat gwewonnen.');
 writeln('Du darfst nur Werte von 3...7 hinzuzaehlen.');
 writeln('Ich starte.');
 writeln('1');
 zStand:= 1;
 add:= 6;

 while zStand < 100 Do
     Begin
     repeat
         writeln ('Du ' );
         readln(Du);
         //pruefe Eingabe, korrekt?
         differenz:= Du-zStand;

         if (differenz < 3) OR (differenz > 7) then
         begin
             writeln('Deine Eingabe war falsch!');
             ok:=false;
         end
         else
         // Eingabe korrekt
            Begin
            ok := true;
            zStand := Du;
            writeln ('Z Stand : ',zStand);
            if zStand = 100 then
                writeln ('Du hast gewonnen!');
            end;
       until ok=true;

        //Computer macht Eingabe

        if zStand <100  then
           begin

           // Bereich 73...77
              if (zStand >= 73) AND (zStand <=77) then
                begin
                 zStand := 80;
                 writeln('Ich:',zStand);
                 ok:= false;
                end;//73..77
           // Bereich 83...87  ?

              if (zStand >= 83) AND (zStand <=87) then
                begin
                 zStand := 90;
                 writeln('Ich:',zStand);
                 ok:= false;
                end;//83..87

           // Bereich 93...97 ?

              if (zStand>= 93 )AND (zStand <= 97 ) then
                begin
                 zStand := 100;
                 writeln('Ich: ',zStand);
                 writeln('Ich habe gewonnen!');
                 ok:= false;
                end;//93..97
                
           // das else bezieht sich nur auf das letzte if .. then!
           
            // Restbereiche
              if ok then
                begin
                  zStand := zStand + add;
                  writeln ('Ich*: ',zStand);
                  ok:= false;
                  add:= add + 1;
                        if add >7 then
                        add := 3;
                 end;//if ok

          end;//<100
     END;//<100
 readln;
end.

Viele Grüße
Bernd

[Atze]

Dankeschön. Ich hatte das Problem auch schon auf diese Weise gelöst. Jedoch ist das nur ein Umgehen des eigentlichen Problems. Wieso bezieht sich das Else nur auf das letzte If? Dann kann man ja keine gestaffelten If Bedingungen mit else einsetzen. Ich bin es von anderen Sprachen gewöhnt, dass ein Else sich auf alle vorherigen Bedingungen bezieht. Wie aber kann man das in Pascal schaffen?
Grüße

[theo]

Warum schmeisst du deine ganze Codesammlung in das Zip?
Ein Snippet (wie unten) hätte übrigens auch gereicht.

Wie aber kann man das in Pascal schaffen?

Meinst du so?

Code: Alles auswählen

  if (zStand >= 73) and (zStand <= 77) then
  begin

  end
  else if (zStand >= 83) and (zStand <= 87) then
  begin

  end
  else if (zStand >= 93) and (zStand <= 97) then
  begin

  end
  else
  begin

  end; 

[Atze]

Genau. In MatLab hat man dazu elseif !
Ich teste es mal, ob es korrekt läuft. Danke. Ich muss mich in Pascal einarbeiten...

[Atze]

Nun das Zippen hat charlytango empfohlen. Ich hatte noch nicht den Code Button im Menü entdeckt... Ich dachte, die lpi Datei beinhaltet den Text Code... wie in Matlab..

[charlytango]

Nun das Zippen hat charlytango empfohlen.

Ja, aber erst nachdem du es nicht geschafft hast ein relevantes Code Snippet zu zeigen.
Dann sichert meine vorgeschlagene Methode dass alle Teile eines Projektes (und nicht nur die *.lpi-Datei) in ein Verzeichnis kopiert werden. Dass auch gezippet werden kann ist nur ein Zusatzgoodie.

... wie in Matlab..

If/elseif/else scheint in Mathlab genauso zu funktionieren wie in vielen anderen Sprachen. Was für mich historisch gesehen auch kein Wunder ist

Wenn man aber mehrere If-Statements verschachtelt muss man aufpassen welches else dann zum Zuge kommt.

[kralle]

Moin,

Warum mit vielen IF-Abfragen arbeiten?
Nehme CASE.
https://wiki.freepascal.org/Case/de

Gruß Heiko

[Atze]

Es läuft jetzt korrekt.
Ich habe das für meinen Enkel geschrieben, falls er Pascal lernen muss. So dachte ich, ich bereite mich mal auf Pascal vor...
Habt ihr schon rausgekriegt, wie man dieses Spiel sicher gewinnt?

Code: Alles auswählen

program Spiel2;
var zStand,add,Du,differenz:integer;
     ok:boolean;

begin
 writeln('Spiele gegen mich');
 writeln('Wer zuerst 100 erreicht, hat gwewonnen.');
 writeln('Du darfst nur Werte von 3...7 hinzuzaehlen.');
 writeln('Ich starte.');
 writeln('1');
 zStand:= 1;
 add:= 6;

 while zStand < 100 Do
     Begin
     repeat
         writeln ('Du ' );
         readln(Du);
         //pruefe Eingabe, korrekt?
         differenz:= Du-zStand;

         if (differenz < 3) OR (differenz > 7) then
         begin
             writeln('Deine Eingabe war falsch!');
             ok:=false;
         end
         else
         // Eingabe korrekt
            Begin
            ok := true;
            zStand := Du;
            writeln ('Z Stand : ',zStand);
            if zStand = 100 then
                writeln ('Du hast gewonnen!');
            end;
       until ok=true;

        //Computer macht Eingabe

        if zStand <100  then
           begin

           // Bereich 73...77
              if (zStand >= 73) AND (zStand <=77) then
                begin
                zStand := 80;
                writeln('Ich:',zStand);
                ok:= false;
                end
           // Bereich 83...87  ?
              else
              if (zStand >= 83) AND (zStand <=87) then
                begin
                zStand := 90;
                writeln('Ich:',zStand);
                ok:= false;
                end

           // Bereich 93...97 ?
              else
              if (zStand>= 93 )AND (zStand <= 97 ) then
                begin
                zStand := 100;
                writeln('Ich: ',zStand);
                writeln('Ich habe gewonnen!');
                end
          // Restbereiche
              else
                  begin
                  zStand := zStand + add;
                  writeln ('Ich: ',zStand);
                  ok:= false;
                  add:= add + 1;
                        if add >7 then
                        add := 3;
                  end;
          end;
     END;
 readln;
end.
[code]

[Atze]

Warum mit vielen IF-Abfragen arbeiten?

Nun, soweit ich das sehe, verlangt case einen einfachen Integer. Da ist nix mit >73 and <77 drin!

[theo]

Warum mit vielen IF-Abfragen arbeiten?

Nun, soweit ich das sehe, verlangt case einen einfachen Integer. Da ist nix mit >73 and <77 drin!

Mit Integer geht das schon. Nur bei Fliesskommazahlen afaik nicht.

Code: Alles auswählen

  case zStand of
    73 .. 77: tuwas;
    83 .. 87: tuwas;
    93 .. 97: tuwas;
    else
      tuwas;
  end;     

[Warf]

Nun, soweit ich das sehe, verlangt case einen einfachen Integer. Da ist nix mit >73 and <77 drin!

Doch klar, Case kann nicht nur einfache werte, sondern auch mehrere werte oder sogar die Möglichkeit einen ganzen Zahlenraum zwischen start und ende anzugeben:

Code: Alles auswählen

  case i of
  3, 7: WriteLn('3 oder 7');
  74..76:
    WriteLn('>73 und <77'); 
  80, 83..85, 89:
    WriteLn('80 oder >82 und <86 oder 89');
  end;  

Aber nur mit Ordinalen typen (Integers, Enums und Chars)