StringList zu C-StrArray umwandeln

[af0815]

Ich habe ein Problem mit dem Umwandeln von einer Stringliste zu einem StringArray ür eine C Bibliothek (libgit2).

Die Definition des Stringarrays in C ist folgendermassen
Original aus der strarray.h

Code: Alles auswählen

/** Array of strings */
typedef struct git_strarray {
	char **strings;
	size_t count;
} git_strarray;

Überstezt nach Pascal in

Code: Alles auswählen

(** Array of strings  *)

type
  git_strarray = record
    strings: PPAnsiChar;
    Count: size_t;
  end;
  Pgit_strarray = ^git_strarray;

meine Umsetzung mittels

Code: Alles auswählen

procedure StringListToGitStrArray(const List: TStringList; out Arr: git_strarray);
var
  i: Integer;
  S: AnsiString;
  Len: SizeUInt;
  P: PPAnsiChar;
begin
  Arr.Count := List.Count;

  if Arr.Count = 0 then
  begin
    Arr.strings := nil;
    Exit;
  end;

  GetMem(Arr.strings, Arr.Count * SizeOf(PAnsiChar));
  P := Arr.strings;
  for i := 0 to Arr.Count - 1 do
  begin
    S := UTF8Encode(List[i])+#0;   // für Git besser
    Len := Length(S);

    GetMem(P^, Len);

    if Len > 0 then
      Move(Pointer(S)^, P^, Len);
    Inc(P);
  end;
end;  

hakt, ich bekomme immer einen GPF (bin unter Linux) in der lib. Aktuell such ich mir einen Wolf und vermute, das ich ganz einfach Betriebsblind bin. Und so ein Pointerfreak bin ich auch nicht. Da habe ich sicher etwas vermurkst, nur sehe ich es nicht.

BTW: Lazarus/FPC main zeigt mir soger die Stellen im C-Code an, da ich die Sourcen von libgit2 am Rechner habe.

[af0815]

Irgendwie hat das Forum auch Probleme, nach dem Editieren ist alles weg, mit der Meldung das der Beitrag nicht existiert.

Neuer (pascalischer) Ansatz:

Code: Alles auswählen

procedure StringListToGitStrArray(const SL: TStringList; out GitArray: git_strarray);
var
  I: Integer;
  PArray: PPAnsiChar;
begin
  GitArray.Count := SL.Count;

  if GitArray.Count = 0 then
  begin
    GitArray.strings := nil;
    Exit;
  end;

  PArray := GetMem(GitArray.Count * SizeOf(PAnsiChar));
  GitArray.strings := PArray;

  for I := 0 to SL.Count-1 do
  begin
    PArray[I] := StrNew(PAnsiChar(AnsiString(SL[I])));
  end;
end;

Sieht einmal besser aus. GPF weg.
Das das Programm noch nicht das macht was ich will, ist eine andere Geschichte.

Edit: Jetzt ist Theo Beitrag weg - dewegen vielleicht die Fehlermeldung und alles aus dem Editor verschwunden.

[theo]

Sry, hatte meinen Beitrag gelöscht, weil er Käse war.
War kurz verwirrt, aufgrund deines AnsiChar.
Das "Ansi" kannst du dir sparen, ist alles dasselbe.

Code: Alles auswählen

  AnsiChar            = Char;
  PAnsiChar           = PChar;
  PPAnsiChar          = PPChar;
  PPPAnsiChar         = PPPChar;    

Ich hüpfe jetzt mal in den See, vielleicht wird's dann besser.

[Zvoni]

Code: Alles auswählen

program Project1;
{$mode ObjFPC}{$H+}
Uses Sysutils, classes;
type
  git_strarray = record
    strings: PPAnsiChar;
    Count: size_t;
  end;
  Pgit_strarray = ^git_strarray;
Var
  SL:TstringList;
  gsa:git_strarray;
  x:Integer;
  P:PPAnsiChar;
procedure StringListToGitStrArray(const List: TStringList; out Arr: git_strarray);
var
  i: Integer;
  S: AnsiString;
  Len: SizeUInt;
begin
  Arr.Count := List.Count;
  if Arr.Count = 0 then
  begin
    Arr.strings := nil;
    Exit;
  end;
  GetMem(Arr.strings, Arr.Count * SizeOf(PAnsiChar));
  for i := 0 to Arr.Count - 1 do
  begin
    S := UTF8Encode(List[i]);   // für Git besser
    Len := Length(S);
    if Len > 0 then
    Begin
      New(Arr.Strings[i]);
      Move(PAnsiChar(s)^,Arr.Strings[i]^,Len+1);
    end;
  end;
End;
begin
  SL:=TStringList.Create;
  SL.Add('Eintrag 1');
  SL.Add('Eintrag 2');
  SL.Add('Eintrag 3');
  SL.Add('Eintrag 4');
  SL.Add('Eintrag 5');
  StringListToGitStrArray(SL,gsa);
  P:=@gsa.strings[0]; //Zeiger auf Anfang der Liste
  For X:=0 To gsa.Count-1 Do
    Begin
      Writeln('Iteration Index: '+gsa.strings[x]);
    end;
  Writeln('----------------------------');
  For x:=0 To gsa.count-1 Do
    Begin
      Writeln('Iteration Zeiger: '+p^);
      Inc(p);
    end;
  Readln;
end.

Kein Anspruch auf Expertentum!!
Und ja: Das Ding leckt wie ne kaputte Heizung.
War ich jetzt zu faul

[theo]

Und ja: Das Ding leckt wie ne kaputte Heizung.

Naja, wenn man nichts freigibt...

Ich hab's mal so angepasst. Scheint zu funzen und heaptrace ist auch happy.
Aber vllt. wird das in AF's Fall vom C code freigegeben.

Code: Alles auswählen

procedure StringListToGitStrArray(const List: TStringList; out Arr: git_strarray);
var
  i: Integer;
  S: AnsiString;
  Len: SizeUInt;
begin
  Arr.Count := List.Count;
  if Arr.Count = 0 then
  begin
    Arr.strings := nil;
    Exit;
  end;
  GetMem(Arr.strings, Arr.Count * SizeOf(PAnsiChar));
  for i := 0 to Arr.Count - 1 do
  begin
    S := UTF8Encode(List[i]);   // für Git besser
    Len := Length(S);
    if Len > 0 then
    Begin
      Arr.Strings[i]:=StrAlloc(Len+1);
      Move(PAnsiChar(s)^,Arr.Strings[i]^,Len+1);
    end;
  end;
End;

procedure TForm1.Button1Click(Sender: TObject);
Var
  SL:TstringList;
  gsa:git_strarray;
  x:Integer;
  P:PPAnsiChar;
begin
    SL:=TStringList.Create;
    SL.Add('Eintrag 1');
    SL.Add('Eintrag 2');
    SL.Add('Eintrag 3');
    SL.Add('Eintrag 4');
    SL.Add('Eintrag 5');
    StringListToGitStrArray(SL,gsa);
    P:=@gsa.strings[0]; //Zeiger auf Anfang der Liste
    For X:=0 To gsa.Count-1 Do
      Begin
        Writeln('Iteration Index: '+gsa.strings[x]);
      end;
    Writeln('----------------------------');
    For x:=0 To gsa.count-1 Do
      Begin
        Writeln('Iteration Zeiger: '+p^);
        StrDispose(p^);
        Inc(p);
      end;
    Freemem(gsa.strings);
    SL.Free;
end;     

[Warf]

Grad nicht am PC zum testen, aber wenn man irgendwie an den internen raw pointer der StringList ran kommt kann man den einfach verwenden. Eine stringlist hat soweit ich weiß intern einfach einen continuous block von strings, die ja C String kompatibel sind.

[af0815]

Grad nicht am PC zum testen, aber wenn man irgendwie an den internen raw pointer der StringList ran kommt kann man den einfach verwenden. Eine stringlist hat soweit ich weiß intern einfach einen continuous block von strings, die ja C String kompatibel sind.

Naja, ich bevorzuge einen Weg,, den ich auch noch morgen verstehe
Und einfach ist es nicht, weil in der Struktur ja nur die Pointer auf die Strings hintereinander liegen, nicht die Strings.

Der zweite Ansatz schaut nicht schlecht aus und macht zumindest keinen GPF. Nachdem das kompilierte C-Beispiel auch nicht unbedingt das macht, was man erwartet, ist die jetzige Lösung mal ok.

Vor allen den Test von Zvoni muss ich mir noch einbauen um die Struktur besser debuggen zu können.

[Warf]

Hat halt den Nachteil das man die ganzen Daten einmal komplett kopieren muss. Je nachdem wie viel das ist kann das schon echt langsam sein und viel Speicher fressen.

Ich hab grade nochmal geschaut, mit TStringList geht es nicht, mit TVector allerdings schon:

Code: Alles auswählen

program Project1;

{$mode objfpc}{$H+}

uses
  heaptrc, gvector;

var
  v: specialize TVector<String>;
  r: record
    strings: PPAnsiChar;
    Count: SizeInt;
  end;
  i: Integer;
begin
  v:=specialize TVector<String>.Create;
  v.PushBack('Entry1');
  v.PushBack('Entry2');
  v.PushBack('Entry3');
  r.strings:=PPAnsiChar(v.Mutable[0]);
  r.Count:=v.Size;

  // Test ob die Daten auch korrekt sind
  for i:=0 to r.Count-1 do
    WriteLn(r.strings[i]);

  // Free'd auch die daten in r.Strings
  v.Free;
end. 

[af0815]

Danke,
die Doku zu TVektor liegt hier, falls sie wer sucht (oder am lokalen Rechner)
https://gitlab.com/freepascal.org/fpc/s ... c/main.pdf

Ich habe aber da noch einen anderen Fehler, den ich suchen muss. Der ist aber in den Demosourcen von Libgit2 selbst

[Mathias]

Eine Warnung vor weg, ich habe gesehen, das ihr Speicher mit GetMem reserviert, diese PChar Array ist nicht voll kompatibel mit C.
Sobald man zB.

Code: Alles auswählen

GIT_EXTERN(void) git_strarray_dispose(git_strarray *array);

aufruft, dann knallt es.
GetMen und FreeMem ist nicht kompatibel zu den C malloc und free.

[Warf]

Dafür kann man den C memory manager (unit cmem als erste unit in der lpr) einbinden. Dann nutzt getmem und freemem (sowie new und dispose) die libc Funktionen malloc und free

[af0815]

Gut zu wissen, nur soweit bin ich nicht. Bei der Lib, darf ich meine eigenen Sachen selbst zerstören, ANsonsten kannich das die Lib machen lassen, soweit ich bisher gekommen bin. Das vereinfacht die Sache, weil ich mich nicht um den Memory Manager kümmern muss.

[Mathias]

Dafür kann man den C memory manager (unit cmem als erste unit in der lpr) einbinden. Dann nutzt getmem und freemem (sowie new und dispose) die libc Funktionen malloc und free

Ich habe mir gerade diese Unit angeguckt, für was baut die soviel overhead ein ?

[Warf]

Zwei Dinge, zum einen C Kompatibilität, damit kann man Speicherallokationen einfach zwischen C und Pascal hin und her reichen und es ist egal wer sie erstellt und wer sie freed. Zum anderen ist der C Memory Manager verdammt schnell, somit kann man in diversen Scenarien einiges an Laufzeit rausholen gegenüber dem Pascal Memory Manager.