For-In-Do mit Components-Liste? [gelöst]

[MmVisual]

Hallo,

Ich wollte einmal die neue For-In-Do testen.

Dazu habe ich den Code:

Code: Alles auswählen

For i := 0 To ComponentCount - 1 Do
    If Components[i] Is TDBGrid Then
      TDBGrid(Components[i]).OnMouseUp := @grdMouseUp;

Umgebaut und sieht jetzt so aus:

Code: Alles auswählen

Var co: TComponent;
 : : :
  For co In Components Do
    If co Is TDBGrid Then
      TDBGrid(co).OnMouseUp := @grdMouseUp;

Aber FPC meckert:
fMain.pas(4722,13) Error: Wrong number of parameters specified for call to "GetComponent"
fMain.pas(4722,13) Error: Cannot find an enumerator for the type "<erroneous type>"

hmm. Was mache ich falsch?

Gruß Markus

[Socke]

TComponente.Components ist eine indizierte Eigenschaft. Die for-in-Schleife kennt aber keine Enumerator-Klasse dafür (die es üblicherweise nur für diverse Listen implementiert sind).

Edit: ich habe gerade einen Enumerator für TComponent geschrieben.

Code: Alles auswählen

// die Enumerator-Klasse
type
  TComponentsEnumerator = class(TObject)
  private
    FParent: TComponent;
    FCurrent: Integer;
  public
    constructor Create(aParent: TComponent);
    function GetCurrent: TComponent;
    function MoveNext: Boolean;
    procedure Reset;
    property Current: TComponent read GetCurrent;
  end;
 
constructor TComponentsEnumerator.Create(aParent: TComponent);
begin
  FParent := aParent;
  Reset;
end;
 
function TComponentsEnumerator.GetCurrent: TComponent;
begin
  Result := FParent.Components[FCurrent];
end;
 
function TComponentsEnumerator.MoveNext: Boolean;
begin
  inc(FCurrent);
  Result := FCurrent < FParent.ComponentCount;
end;
 
procedure TComponentsEnumerator.Reset;
begin
  FCurrent := -1;  // das erste MoveNext() setzt FCurrent = 0
end;
 
// einen Operator, der die richtige Enumerator-Klasse instantiiert
operator Enumerator(aParent: TComponent): TComponentsEnumerator;
begin
  Result := TComponentsEnumerator.Create(aParent);
end;
 
// Aufruf
var
  co: TComponent;
for co in Self do  // Self muss durch die Komponente ersetzt werden, durch dessen Kind-Komponenten man iterieren will
  ShowMessage(co.Name);

[MmVisual]

edit:
Ich habe den Code so geändert:

Code: Alles auswählen

For co In Self Do

Dann ging es , den Enumerator braucht es nicht extra (oder ist in meinem Lazarus schon drin)

Grüße und frohe Weihnachten Markus

[Socke]

Dann ging es , den Enumerator braucht es nicht extra (oder ist in meinem Lazarus schon drin)

Naja, das hätte ich auch selbst überprüfen können , aber wenn man so wenig ausgelastet ist, schießt man schonmal übers Ziel hinaus.

[af0815]

Dann ging es , den Enumerator braucht es nicht extra (oder ist in meinem Lazarus schon drin)

Ist etwas das nicht Lazarus, sondern der FPC bereistellt, steht auch eindeutig im Referenceguide im Kapitel "The For..in..do Statement drinnen

Code: Alles auswählen

The Classes unit contains a number of classes that are enumerable:
 
TFPList
    Enumerates all pointers in the list. 
TList
    Enumerates all pointers in the list. 
TCollection
    Enumerates all items in the collection. 
TStringList
    Enumerates all strings in the list. 
TComponent
    enumerates all child components owned by the component.