Systemsprache nutzen?

[Komoluna]

Hallo Leute

Ich wüsste gerne wie man (als Programm) die Systemsprache herausfinden kann, denn ich entwickle gerade ein Multi-Language-Programm
was beim ersten Programmstart die Systemsprache herausfinden soll.

Die Lösung sollte am besten Plattform-unabhängig sein.

Vielen Dank schonmal im voraus.

Komoluna

[theo]

Code: Alles auswählen

uses gettext;
 
...
var l,fbl:String;
begin
  GetLanguageIDs(l,fbl);
  ShowMessage(fbl);
end;

[jwdietrich]

Code: Alles auswählen

uses gettext;
 
...
var l,fbl:String;
begin
  GetLanguageIDs(l,fbl);
  ShowMessage(fbl);
end;

Also, am Mac funktioniert das nicht, da werden leere Strings zurückgegeben.

Plattformunabhängig ist diese Lösung also nicht.

[theo]

Also, am Mac funktioniert das nicht, da werden leere Strings zurückgegeben.

Plattformunabhängig ist diese Lösung also nicht.

http://lazarus-ccr.sourceforge.net/docs ... geids.html" onclick="window.open(this.href);return false;

[jwdietrich]

Also, am Mac funktioniert das nicht, da werden leere Strings zurückgegeben.

Plattformunabhängig ist diese Lösung also nicht.

http://lazarus-ccr.sourceforge.net/docs ... geids.html" onclick="window.open(this.href);return false;

Das mag ja sein, aber es funktioniert nicht.

[theo]

Das mag ja sein, aber es funktioniert nicht.

Sind beide Parameter der Funktion leer? Dann schau doch mal, was da schief läuft auf deinem System.

[Scotty]

Die Funktion greift auf die Systemvariablen LC und LANG zurück.

Code: Alles auswählen

procedure GetLanguageIDs(var Lang, FallbackLang: string);
begin
  lang := GetEnvironmentVariable('LC_ALL');
  if Length(lang) = 0 then
  begin
    lang := GetEnvironmentVariable('LC_MESSAGES');
    if Length(lang) = 0 then
    begin
      lang := GetEnvironmentVariable('LANG');
      if Length(lang) = 0 then
        exit;   // no language defined via environment variables
    end;
  end;
  FallbackLang := Copy(lang, 1, 2);
end;

Du kannst diese Variablen per "export" in der Konsole anzeigen lassen. Interessant ist auch die Funktion locale (https://developer.apple.com/library/mac ... ale.1.html).

[jwdietrich]

Nach stundenlangem Recherchieren habe ich jetzt eine Lösung gefunden, die zumindest für Mac OS X und Windows funktioniert. Für Linux muss noch eine Lösung gesucht werden.

Code: Alles auswählen

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, StdCtrls,
  gettext
{$IFDEF win32}
, Windows
{$ELSE}
  {$IFDEF LCLCarbon}
, MacOSAll
  {$ENDIF}
{$ENDIF}
;        

...
 

Code: Alles auswählen

var 
  l, fbl: String;
{$IFDEF LCLCarbon}
  theLocaleRef: CFLocaleRef;
  locale: CFStringRef;
  buffer: StringPtr;
  bufferSize: CFIndex;
  encoding: CFStringEncoding;
  success: boolean;
{$ENDIF}

...
 

Code: Alles auswählen

begin
  {$IFDEF win32}
    GetLanguageIDs(l,fbl);
  {$ELSE}
    {$IFDEF LCLCarbon}
      theLocaleRef := CFLocaleCopyCurrent;
      locale := CFLocaleGetIdentifier(theLocaleRef);
      encoding := 0;
      bufferSize := 256;
      buffer := new(StringPtr);
      success := CFStringGetPascalString(locale, buffer, bufferSize, encoding);
      if success then
        fbl := string(buffer^)
      else
        fbl := '';
    {$ENDIF}
  {$ENDIF}
  ShowMessage(fbl);
end;

[jwdietrich]

Anbei nun eine erweiterte Fassung der Routine, die jetzt auch unter Linux läuft (getestet mit openSUSE 11):

Code: Alles auswählen

uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, StdCtrls,
  gettext
{$IFDEF win32}
, Windows
{$ELSE}
  {$IFDEF LCLCarbon}
, MacOSAll
  {$ENDIF}
{$ENDIF}
;

Code: Alles auswählen

var 
  l, fbl: String;
{$IFDEF LCLCarbon}
  theLocaleRef: CFLocaleRef;
  locale: CFStringRef;
  buffer: StringPtr;
  bufferSize: CFIndex;
  encoding: CFStringEncoding;
  success: boolean;
{$ENDIF}

Code: Alles auswählen

begin
  {$IFDEF LCLCarbon}
    theLocaleRef := CFLocaleCopyCurrent;
    locale := CFLocaleGetIdentifier(theLocaleRef);
    encoding := 0;
    bufferSize := 256;
    buffer := new(StringPtr);
    success := CFStringGetPascalString(locale, buffer, bufferSize, encoding);
    if success then
      l := string(buffer^)
    else
      l := '';
    fbl := Copy(l, 1, 2);
    dispose(buffer);
  {$ELSE}
  {$IFDEF LINUX}
      fbl := Copy(GetEnvironmentVariable('LC_CTYPE'), 1, 2);
    {$ELSE}
      GetLanguageIDs(l,fbl);
    {$ENDIF}
  {$ENDIF}
    ShowMessage(fbl);
end;

Der Code ist jetzt also insofern plattformunabhängig als er unter Windows, Desktop Linux und Mac OS X läuft. Es liefert einen Zwei-Buchstaben-ISO-Code für die aktuell eingestellte Sprache des Betriebssystems zurück, z. B. "de" für Deutsch oder "en" für Englisch.

Um Android, Solaris und BSD muss sich jemand anders kümmern, da mir hier die Expertise fehlt. Wahrscheinlich funktioniert es dort so ähnlich wie unter Linux.