[gelöst]Programm aus FormCreate beenden 2te

[noenglish]

Ich möchte ein Programm (nach einer Prüfung) beenden bevor die erste Form erzeugt wird. Das selbe Problem wurde schon hier:
http://www.lazarusforum.de/viewtopic.ph ... ate#p45307
beschrieben. Ich möchte wie oben empfohlen die Prüfung in der Projektdatei durchführen, habe aber keine Ahnung wie ich Funktionen und Prozeduren in der Projektdatei unterbringe.
Kann mir jemand ein Beispiel nennen?

Ich kann mir auch vorstellen die Prüfung in eine Unit zu schreiben und die Prüfung aufzurufen bevor die erste Form erzeugt wird. Aber auch da, keine Ahnung.

Im voraus besten Dank.
noenglish

[wp_xyz]

Einfach die Unit mit den Testprozeduren in die Uses-Liste der Projekt-Datei aufnehmen.

Code: Alles auswählen

 
program Project1;
 
{$mode objfpc}{$H+}
 
uses
  {$IFDEF UNIX}{$IFDEF UseCThreads}
  cthreads,
  {$ENDIF}{$ENDIF}
  Interfaces, // this includes the LCL widgetset
  Forms, Unit1, 
  Unit2,   // Prüf-Unit
  Dialogs  // für die Fehlermeldung
  { you can add units after this };
 
{$R *.res}
 
begin
  RequireDerivedFormResource := True;
 
  if not BasicCheck then begin           // Prüfen...
    ShowMessage('Syntax: ....');         // Fehlermeldung ausgeben
    halt;                                // Programm beenden 
  end;
 
  Application.Initialize;
  Application.CreateForm(TForm1, Form1);
  Application.Run;
end. 
 
--------------------------------------------------
 
unit Unit2;
 
{$mode objfpc}{$H+}
 
interface
 
uses
  Classes, SysUtils;
 
function BasicCheck: Boolean;
 
implementation
 
function BasicCheck: Boolean;
// Hier müsste natürlich etwas Sinnvolles stehen...
// Prüfe hier, ob Kommandozeilenparameter angegeben sind. Wenn nicht, soll das Programm abbrechen.
begin
  if ParamCount = 0 then
    Result := false
  else
    Result := True;
end;
 
end.
 

[noenglish]

Funktioniert!
wp_xyz, vielen Dank für schnelle und hielfreiche Antwort!

noenglish