Konstruktorfehler und anderer

[max_itn]

Hallo Leute,
ich habe eine Frage zum Aufruf, beziehungsweise Inhalt eines Konstruktors bei einer grafischen Anwendung.
Die Elemente sollen in einer Objektliste gespeichert werden.
Diese Objektliste soll beim Erzeugen des Fensters mit der Create instanziiert werden.
Siehe:

Code: Alles auswählen

Constructor TForm1.Create;
begin
  inherited Create(Self);
  MyObjectList.create;
end;                         

Hierfür erhalte ich folgende Fehlermeldung:
test_eigenes_label2_unit2.pas(55,20) Error: method identifier expected
test_eigenes_label2_unit2.pas(57,13) Error: Methods can be only in other methods called direct with type identifier of the class
test_eigenes_label2_unit2.pas(57,13) Fatal: Syntax error, ";" expected but "identifier CREATE" found

Hier die Definition von TForm1:

Code: Alles auswählen

 
type
 
  { TForm1 }
 
  TForm1 = class(TForm)
    Button1: TButton;
    Label1: TLabel;
 
   procedure Button1Click(Sender: TObject);
 //   procedure FormMouseEnter(Sender: TObject);
 
  private
    { private declarations }
 
  public
    { public declarations }
   MyObjectList: TObjectList;
    constructor Ceate;
  end;          

Was kann ich tun um diese Fehlermeldung zu beseitigen?
Wird durch den Aufruf inherited Create(Self) das Fenster gezeichnet?
Oder wo geschieht das?
Wofür ist der Parameter „self“ gut?
Vielen Dank für die Beantwortung dieser Frage.
Mfg max_itn

[theo]

Du solltest nicht Create überschreiben, sondern das Ereignis OnCreate des Formulars verwenden.
Und nicht
MyObjectList.create;
sondern:
MyObjectList:= TObjectList.Create;

[Mathias]

Code: Alles auswählen

constructor Ceate;

Sollte wohl Create heisen.

[wp_xyz]

Und Create verlangt einen Parameter "Owner", der die erzeugte Instanz am Ende wieder freigibt. Und Create ist virtuell und braucht den Zusatz "override". "Self" bezieht sich auf die gerade erzeugte Instanz - sowas wie "Create(self)" bedeutet später "Selbstmord", verwende stattdessen den Owner-Parameter, der dem Constructor mitgegeben wird. Und die ObjectList, die du im Constructor erzeugst, musst du selbst wieder aufräumen (--> Destroy):

Code: Alles auswählen

 
type
  TForm1 = class(TForm)
    Button1: TButton;
    Label1: TLabel;
    procedure Button1Click(Sender: TObject);
  private
    { private declarations }
  public
    { public declarations }
    MyObjectList: TObjectList;
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;
  end;
 
constructor TForm1.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
  MyObjectList := TObjectList.Create;
end;
 
destructor TForm1.Destroy;
begin
  MyObjectList.Free;
  inherited Destroy;
end;