String in Zahlen zerlegen

[Mathias]

Gibt es eine fertige Funktion, welche Zahlen aus einem String auslesen kann ?

Oder muss ich mühsam mit Pos und Copy den String zerlegen, bevor ich die Zahlen mit Val/StrToInt/StToFloat in einen Integer/Single konvertieren kann ?

Code: Alles auswählen

1234 5678 9012
111.111 222.222 333.333

Bei dem Beispiel oben, hat es in der 1. Zeile 3 Integer und in der zweiten Zeile 3 Single.

[TBug]

Oder muss ich mühsam mit Pos und Copy den String zerlegen, bevor ich die Zahlen mit Val/StrToInt/StToFloat in einen Integer/Single konvertieren kann ?

Du kannst zum Trennen der einzelnen Werte eine Stringliste benutzen und den entsprechenden Delemiter setzen und den Ausgangsstring der Property Text zuweisen.
Danach hast Du alle "Zahlen-Strings" einzeln und kannst sie bequem durchlaufen und in den gewünschten Typ umwandeln.


.

[Mathias]

Habe folgenden Test probiert, aber bei Count kommt 1, und sl[0] beinhaltet den ganzen String.
Muss ich noch etwas aufrufen, das sl die Strings trennt ?

Code: Alles auswählen

procedure TForm1.Button1Click(Sender: TObject);
const
  s = '123 456 678 901';
var
  sl: TStringList;
begin
  sl := TStringList.Create;
  sl.Text := s;
  sl.Delimiter := ' ';
  ShowMessage(IntToStr(sl.Count));
  ShowMessage(sl[0]);
  sl.Free;
end;    

[Achtzig]

Du müstest erst den Delimiter setzen und dann DelimitedText anstatt Text verwenden:

Code: Alles auswählen

 
  sl.Delimiter := ' ';
  sl.DelimitedText := s;
 

[Mathias]

Danke, jetzt geht's.
TStringList ist ja ein richtig mächtiges Werkzeug.

Code: Alles auswählen

procedure TForm1.Button1Click(Sender: TObject);
const
  s = '123 456 678 901';
var
  sl: TStringList;
begin
  sl := TStringList.Create;
  sl.Delimiter := ' ';
  sl.DelimitedText := s;
  ShowMessage(IntToStr(sl.Count));
  ShowMessage(sl[0]);
  sl.Free;
end; 

[marcov]

Ein anderer Anflug:

Code: Alles auswählen

var s : string;
    i,j,k : integer;
    ri,rj,rk : real;
 
begin
 s:='1234 5678 9012';
 readstr(s,i,j,k);
 writeln(i,'-',j,'-',k);
 
 s:='111.111 222.222 333.333'; rk:=10;
 readstr(s,ri,rj,rk);
 writeln(ri:7:3,'-',rj:7:3,'-',rk:7:3);
end.

Wenn man versucht mehr Variablen zu lesen dan drin sein, werden diejenige Variablen auf 0 gesetzt.

[Mathias]

Dies ist sicher eine gute Variante, nur ist bei mir die Anzahl der Zahlen im String unbekannt, und es kann auch eine "0" im String sein, somit eignet sich im meinem Fall die Lösung mit TStringList besser.

Trotzdem Danke!

[theo]

Oder muss ich mühsam mit Pos und Copy den String zerlegen,

Nein, das muss man sowieso nicht. Das Ganze ist eine einfache Fingerübung, die man auch mit ganz wenig nachdenken lösen kann.

Code: Alles auswählen

 
var
  s, buf: string;
  i: integer;
begin
  s := '111.111 222.222 333.333';
  buf := '';
  for i := 1 to length(s) do
    if (s[i] = ' ') then
    begin
      ShowMessage(buf);
      buf := '';
    end else buf := buf + s[i];
  if buf <> '' then ShowMessage(buf);
end;    

Wegen jedem Mückenschiss eine fertige Funktion zu suchen, kann ganz schön anstrengend sein. Deshalb kann man ruhig auch mal etwas selber machen.
Die Lösung mit der StringList ist allerdings schon gut.

[Michl]

...ein Codecontest - ich bin dabei

Ich benutze gern in solchen Fällen ExtractWord

Das Ganze könnte dann z.B. so aussehen:

Code: Alles auswählen

uses ..., StrUtils;
...
var
  s, buf: string;
  i: integer;
begin
  s := '111.111 222.222 333.333';
  for i := 1 to Length(s) do
  begin
    buf := ExtractWord(i, s, [' ']);
    if Length(buf) > 0 then
      ShowMessage(buf)
    else
      Break;
  end;
end;  

[theo]

...ein Codecontest - ich bin dabei

Du verwendest aber eine vorgefertigte Funktion. Das zählt nicht.

[Michl]

Du verwendest aber eine vorgefertigte Funktion. Das zählt nicht.

Das wusste ich nicht. Bin ich nun disqualifiziert oder habe ich noch einen Versuch?

Vielleicht nicht so schön, wie der vorherige Versuch, dafür verdiene ich mir doch bestimmt einen Extrapunkt für die Rekursion?!

Code: Alles auswählen

procedure TForm1.Button1Click(Sender: TObject);
begin
  ExtractRecursive('111.111 222.222 333.333');
end;
 
procedure TForm1.ExtractRecursive(const s: String);
var
  buf: string;
  i: Integer;
begin
  i := 1;
  buf := '';
  while (i <= Length(s)) and (s[i] <> ' ') do
  begin
    buf := buf + s[i];
    inc(i);
  end;
  if Length(buf) > 0 then
    ShowMessage(buf);
  if i > Length(s) then Exit;
  ExtractRecursive(Copy(s, i + 1, Length(s)));
end;
 

[theo]

Du verwendest aber eine vorgefertigte Funktion. Das zählt nicht.

Das wusste ich nicht. Bin ich nun disqualifiziert oder habe ich noch einen Versuch?

Meinetwegen. Eine Variante mit PChar wäre auch schön.

buf := buf + s könnte man auch schöner machen bzgl. Speicher Reservierung.

Assembler muss nicht, aber kann!!

Nö, ich wollte dem OP eigentlich nur zeigen, dass es einfach ist und kein Copy/Pos benötigt.

[Mathias]

So sieht nun die fertige Function aus:

Code: Alles auswählen

  function getInt(ins: ansistring): TIntArray;
  var
    i: integer;
    sl: TStringList;
  begin
    sl := TStringList.Create;
    sl.Delimiter := ' ';
    sl.DelimitedText := ins;
 
    SetLength(Result, sl.Count);
    for i := 0 to sl.Count - 1 do begin
      Result[i] := StrToInt(sl[i]);
    end;
 
    sl.Free;
  end;

Soviel ich wies, ist buf := buf + s sher Rechenintensiv.

[theo]

Soviel ich wies, ist buf := buf + s sher Rechenintensiv.

Naja, es wird ein bisschen Speicher reserviert. Ob TStringList als "Black Box" benutzt wirklich effizienter ist, weisst du nicht.

[tryunderror]

Gibt es eine fertige Funktion, welche Zahlen aus einem String auslesen kann ?

Oder muss ich mühsam mit Pos und Copy den String zerlegen, bevor ich die Zahlen mit Val/StrToInt/StToFloat in einen Integer/Single konvertieren kann ?

Code: Alles auswählen

1234 5678 9012
111.111 222.222 333.333

Bei dem Beispiel oben, hat es in der 1. Zeile 3 Integer und in der zweiten Zeile 3 Single.

Ich mische mal ein mit ganz anderen Argumenten. Warum Prozeduren im Alltag benutzen wie TStringList.Create.

Wenn man im Alltag zb mit Texten und Zahlen und Konvertierung zu tun hat
dann schreibt man doch mit einfachen Pascal Prozeduren sich selbst die Tools mit zb ord(ch) zum Integerwert. Erstens kenne ich dann die Befehle und kann besser absichern mit Abfragen als ein fremdes Tool.